Files
Create points at a curve intersections
Code
'Precondition: Two sketches are selected in the FM tree
'Result: A sketch pt is intersected with each combination of sketch segments from both _
selected sketches
'Written by Keith Rice
'CADSharp LLC
'www.cadsharp.com
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swSelMgr As SldWorks.SelectionMgr
Dim swSketchFeat As SldWorks.Feature
Dim swSketch1 As SldWorks.Sketch
Dim swSketch2 As SldWorks.Sketch
Dim vSketch1Segs As Variant
Dim vSketch2Segs As Variant
Dim swSketchSeg As SldWorks.SketchSegment
Dim swSketchPt As SldWorks.SketchPoint
Dim i As Integer
Dim j As Integer
Dim strPlane As String
Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
'Error handling
If swModel Is Nothing Then
Call ErrorHandler
End If
Set swSelMgr = swModel.SelectionManager
If swSelMgr.GetSelectedObjectCount2(-1) <> 2 Then
Call ErrorHandler
End If
For i = 1 To 2
If swSelMgr.GetSelectedObjectType3(i, -1) <> swSelSKETCHES Then
Call ErrorHandler
End If
Next i
'Get sketch segments
Set swSketchFeat = swSelMgr.GetSelectedObject6(1, -1)
Set swSketch1 = swSketchFeat.GetSpecificFeature2
Set swSketchFeat = swSelMgr.GetSelectedObject6(2, -1)
Set swSketch2 = swSketchFeat.GetSpecificFeature2
vSketch1Segs = swSketch1.GetSketchSegments
vSketch2Segs = swSketch2.GetSketchSegments
'Prompt user for plane on which sketches are located
strPlane = InputBox _
("Enter the exact name of the reference plane on which the selected sketches reside.")
'Create new "results" sketch
Set swSketchFeat = swModel.FirstFeature
i = 0
Do While Not swSketchFeat Is Nothing
If swSketchFeat.Name = strPlane Then Exit Do
Set swSketchFeat = swSketchFeat.GetNextFeature
Loop
swSketchFeat.Select2 False, 0
swModel.SketchManager.InsertSketch True
'Prevent snapping
swModel.SketchManager.AddToDB = False
'Create a sketch pt for each sketch segment in first array
For i = 0 To UBound(vSketch1Segs)
For j = 0 To UBound(vSketch2Segs)
'create sketch pt
Set swSketchPt = swModel.SketchManager.CreatePoint(1, 1, 0)
'select a seg from first sketch and sketch pt
Set swSketchSeg = vSketch1Segs(i)
swSketchSeg.Select4 False, Nothing
swSketchPt.Select4 True, Nothing
'select a seg from second sketch and sketch pt
Set swSketchSeg = vSketch2Segs(j)
swSketchSeg.Select4 True, Nothing
swSketchPt.Select4 True, Nothing
'add intersection constraint
swApp.RunCommand swCommands_Add_Constraint_Atinter, Empty
Next j
Next i
'exit sketch
swModel.SketchManager.InsertSketch True
'restore snapping
swModel.SketchManager.AddToDB = True
End Sub
Sub ErrorHandler()
MsgBox "Please open a part and select two sketches from the FeatureManager tree."
End
End Sub