Files
Lesson 5.3 - modify transform using ArrayData Associated model(s)
Code
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swAssy As SldWorks.AssemblyDoc
Dim swComp As SldWorks.Component2
Dim swMathUtil As SldWorks.MathUtility
Dim swTransform As SldWorks.MathTransform
Dim swNewTransform As SldWorks.MathTransform
Dim vData As Variant
Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swAssy = swModel
Set swComp = swAssy.GetComponentByName("block-1")
Set swMathUtil = swApp.GetMathUtility
'Get transform
Set swTransform = swComp.Transform2
'Get transform data
vData = swTransform.ArrayData
'Modify transform data
Dim deg As Double
Dim rad_per_deg As Double
rad_per_deg = 4 * Atn(1) / 180
deg = 45
'X axis components of rotation
vData(0) = Round(Cos(deg * rad_per_deg), 4)
vData(1) = Round(-1 * Sin(deg * rad_per_deg), 4)
vData(2) = 0
'Y axis components of rotation
vData(3) = Round(Sin(deg * rad_per_deg), 4)
vData(4) = Round(Cos(deg * rad_per_deg), 4)
vData(5) = 0
'Z axis components of rotation
vData(6) = 0
vData(7) = 0
vData(8) = 1
'translation
vData(9) = 0
vData(10) = 0
vData(11) = 0
'Re-create transform from modified data
Set swNewTransform = swMathUtil.CreateTransform(vData)
Set swNewTransform = swTransform.Multiply(swNewTransform)
'Set component transform and update model
swComp.Transform2 = swNewTransform
swModel.ForceRebuild3 False
End Sub